Author Archives: 發財橘子

改良版的移動平均線~四大力道線

我們經常用收盤價作移動平均線，然後尋找不同天期的均線，出現黃金交叉時買進，出現死亡交叉時賣出。

之所以這麼做，是因為我們覺得收盤價是當天多空爭戰的最後結果，所以拿收盤價的移動平均代表了一段時間多空爭戰的軌跡。

但如果我們細看每根K棒，我們其實除了收盤價之外，還有當天的開盤價，最高價，最低價，我們可以運用這些價位，更精確的勾勒出當天多空爭鬥的力道。

就像上面的這張圖
我們可以
1.把每天最高價到收盤價的距離，視為當天上檔的賣壓
2.把每天最低價到收盤價的距離，視為下檔的支撐
3.把每天開盤價到收盤價之間的距離，視為多方或空方的戰績
4.把前一天收盤價到今天開盤價的距離，視為前一日收盤後多空消息消化後的結果

當我們把這種多空力道都考慮進去之後，我們可以計算一段時間這些力道的總和，這樣的總和，會比收盤價更能表現出這檔商品多空力道的消張。

根據這樣的想法，我寫了一個指標，這個指標的寫法如下:

input:days(10),period(20);
setinputname(1,"短期參數");
setinputname(2,"長期參數");

value1=summation(high-close,period);//上檔賣壓
value2=summation(close-open,period); //多空實績
value3=summation(close-low,period);//下檔支撐
value4=summation(open-close[1],period);//隔夜力道
if close<>0
then
value5=(value2+value3+value4-value1)/close;
value6=average(value5,days);
plot1(value5,"四大力道線");
plot2(value6,"移動平均線");

我把這個指標稱為四大力道線
從上圖我們可以發現，這個指標在趨勢轉折時，比較可以敏感地偵測出多空力道的微妙變化，在盤整時，則會在零附近呈現鋸齒狀波動。

所以我們可以拿這個指標，來輔助我們找到多空方向在微妙轉變的股票。

盤感好的股票

漲跌幅放寬到一成之後，有愈來愈多的操作者，更用力的砥礪自己的當沖技能，想要享受一天賺10%的快感。

朋友中的強者，一直跟我強調，如果要做當日沖，根本不要管什麼基本面，籌碼面，這些都是歷史，最重要的是當天的盤感。

盤感好的股票易漲難跌。

我根據他的說法，寫了一個即時的腳本如下:

value1=q_AvgLongUnits;//委買均張
value2=q_AvgShortUnits;//委賣均張
value3=q_InSize;//當日內盤量
value4=q_OutSize;//當日外盤量

value5=q_BestBidSize;//委買張數
value6=q_BestAskSize;//委賣張數
value9=q_BestBidSize1;//委買一張數
value10=q_BestAskSize1;//委賣一張數
value11=q_BestBidSize2;
value12=q_BestAskSize2;
value13=q_BestBidSize3;
value14=q_BestAskSize3;
value15=q_BestBidSize4;
value16=q_BestAskSize4;
value17=q_BestBidSize5;
value18=q_BestAskSize5;
condition1=false;
condition2=false;

if value1-value2>1 and value4>value3 and value5-value6>200
then condition1=true;

if minlist(value9,value11,value13,value15,value17)>50
and maxlist(value10,value12,value14,value16,value18)<30
then condition2=true;
if condition1 and condition2 then ret=1;

他的精神很簡單，就是當天外盤成交的多，委買的是大咖的，委賣的是散單
然後五檔委買勇於掛進，掛在五檔委賣的都是小單

他認為這種股票比較有機會收上去。

各位可以拿這腳本做基礎，改成您的盤感偵測器。

靜極思動

漲跌幅開放到10%之後，我們初步發現，羊群效應更明顯，大家更只願意在熱門股中交易，對於那些冷門股，就算再便宜，在沒有出量之前，大家都興趣缺缺，因為漲跌幅放寬大家會更重視流動性的問題。

但熱門股漲太多時，多少會有點買不下手。

於是，我想了幾個原則，來去找那些才剛轉熱沒多久的股票，我設了幾個條件

1.近三天的平均真實波動區間比過去十五日的真實波動區間大超過2%

2.近三天的平均成交量比過去十五天平均成交量高出2成以上

3.最高價比過去五天的最高價還高

4.成交量大於五百張

根據這些條件，對應的腳本如下

input:r1(3),r2(15),r3(5);
setinputname(1,"短天期均量及真實波動區間的長度");
setinputname(2,"長天期均量及真實波動區間的長度");

settotalbar(100);

if average(truerange,r1) >= average(truerange,r2)*1.02
and average(volume,r1)>=average(volume,r2)*1.2
and high>=highest(high[1],r3)
and close<=close[r3]*1.1
and volume>500
then ret=1;

WVAD威廉變異離散量

WVAD威廉變異離散量的理論，建立在幾個基礎上
1.每天的收盤價減開盤價，是當天盤中多空真正的角力結果
2.每天的最高價減去最低價，則是多空拉距過的最大痕跡
3.所以真正可以代表多空力道的成交量，應該是第一項除以第二項之後的比例去乘以當天的成交量。
4.把每天的這個成交量累計五天，就是WVAD威廉變異離散量

以下是根據這樣的理論所寫出來的腳本

input:length(5);
variable:wvad(0);
value1=close-open;
value2=high-low;
if high<>low
then value3=value1/value2*volume
else
value3=value3[1];
wvad=summation(value3,length);
plot1(wvad,"威廉變異離散量");
plot2(0);

因為它的計算原理是這樣來的，所以在應用上大約可以把握幾個原則

1.指標由負翻正代表近五日盤中買力贏過賣力，是短多的徵候。

2.指標低檔或高檔背離是一個領先的反轉訊號

3.在零附近游走代表多空勢力相差不大。

Q指標

看到Q您會想起誰? Meggi Q ，這麼回答的可不是技術指標狂，做為一個技術分析重度狂熱者，看到Q就想到Q指標。

這個指標的設計蠻有意思，它的概念是這樣

1.先算出一定期間內，每天的收盤價跟前一天收盤價差的累計值。這個值如果股價一路往上，愈漲愈兇時會一路走高，相反的，如果是一路走低愈跌愈傪時會一路下跌，如果是盤整盤，那就在零上下波動。

2.把一段期間來，每天股價漲跌取絕對值，然後再算這段期間的移動平均值，這個值就是這檔股票每天平均的漲跌值。

3.然後把這兩個值相除再乘以5，代表的是這檔股票短期內的漲跌累計值的移動平均，和較長期間的波動絕對值相比，佔的比例是多少?

對應的腳本如下:

input:t1(10);
input:t2(5);
input:t3(20);
setinputname(1,"計算累積價格變動的bar數");
setinputname(2,"計算價格累積變化量移動平均的期別");
setinputname(3,"計算雜訊的移動平均期別");
value1=close-close[1];//價格變化
value2=summation(value1,t1);//累積價格變化
value3=average(value2,t2);
value4=absvalue(value2-value3);//雜訊
value5=average(value4,t3);//把雜訊移動平均
variable:Qindicator(0);
if value5=0
then Qindicator=0
else
Qindicator=value3/value5*5;
plot1(Qindicator,"趨勢值");

如果這個值大於零，代表最近的累積上漲幅度比跌幅度大。
這個值愈高，代表漲勢愈大。

相反地，低於零代表在漲少跌多。

這個指標的妙用之處是在於化繁為簡，看K線看到眼花時，看看Q指標，就知道現在到底趨勢是在那邊

如果在零以下打平後往上走，就是個買進訊號

如果在零以上打平後往下彎，就是個賣出訊號

克林格成交量擺動指標Klinger Oscillator, KO是一個與成交量又關的股票技術指標，它是由Stephen J. Klinger所發明的。以下介紹一下這個技術指標的計算方法和它在股票交易中的使用方法。
克林格成交量擺動指標Klinger Oscillator的計算方法：
首先，計算股票在每個交易日的平均價格=（收盤價+最高價+最低價）/3
如果，平均交易價格高於前一日的平均交易價格，那麼當日的股票成交量為正值；平均交易價格低於前一日的平均交易價格，那麼當日的股票成交量為負值。
然後，計算34天和55天（正負處理後的）成交量的指數移動平均值；這兩者的差值就是克林格成交量擺動指標Klinger Oscillator。為了更好的觀察這個指標的趨勢，還可以計算這個技術指標的13天指數移動平均值。

value1=(close+high+low)/3;
variable:v1(0);
if value1>=value1[1]
then v1=volume
else v1=volume*(-1);

value2=average(v1,34);
value3=average(v1,55);
value4=value2-value3;
value6=average(value4,3);
value5=average(value4,13);
plot1(value6);
plot2(value5);

這個技術指標的目的是為了觀察短期和長期股票資金的流入和流出的情況。它的主要用途是確認股票價格趨勢的方向和強度。如果用它來判斷股價趨勢方向，就要看這個指標的擺動範圍所處的相對位置。如果股價是上升趨勢，它的擺動範圍靠上（大於0的方向）；如果是下降趨勢，它的擺動範圍靠下（小於0的方向）。如果用它來判斷股價趨勢的強弱就要看這個指標與股票價格之間有沒有背離現象出現。股票價格下跌，KO指標出現多頭背離，那麼交易方向為買入；股票價格上漲，KO指標出現空頭背離，那麼就要伺機做空股票。

％B指標

%B這個指標，是從佈林值演化過來的，我們要了解%B指標前，先來溫習一下佈林通道(BBand)

Input: price(numericseries), length(numericsimple), _band(numericsimple);

BollingerBand = Average(price, length) + _band * StandardDev(price, length, 1);

從上述的程式，我們了解，布林值的上下兩條線就是移動平均線各加減N個標準差。而％B則是在(收盤價 – 布林帶下軌值) ÷ (布林帶上軌值 – 布林帶下軌值)
從這個公式來看，當收盤價愈貼近布林值下軌道線，且上下兩條線差距很大時，%B的值愈趨近於零，如果收盤價都穿過布林值上軌道線了，％B的值就會大於一。

所以如果%B從0.5以下，突破自己的五日平均線，是翻多的訊號，相反的，如果在１以上，則短線有過熱的徵候。

以下就是%B的腳本

input: Length(20);	SetInputName(1, "布林通道天數");
input: BandRange(2);SetInputName(2, "上下寬度");
input: MALength(10);SetInputName(3, "MA天期");

variable: up(0), down(0), mid(0);

up = bollingerband(Close, Length, BandRange);
down = bollingerband(Close, Length, -1 * BandRange);

if up - down = 0 then value1 = 0 else value1 = (close - down) * 100 / (up - down);
value2 = average(value1, MALength);

Plot1(value1, "%b");
Plot2(value2, "%b平均");

DKX多空線

DKX多空線的設計是希望可以儘快的找到市場的真正多空趨向
它用了兩個方法
１．用中價來代替收盤價作為計算的基準
中價的算法是用(收盤價*3+開盤價+最高價+最低價)/6
這樣的作法是又有考慮到其他三個價位的代表性，又特別強調收盤價才是一天多空的均衡點

２．它在計算多空線時，拿過去二十日的中價作平均，但愈接近現在的那根BAR權值愈重。
所以他算出來的這個多空線的位置，是經過二十個中價作加權平均出來的。

至於它的應用很容易
１．收盤指數突破多空線即翻多。
２．收盤指數跌破多空線即翻空。

以下是DKX多空線的腳本

variable:MID(0),midsum(0),DKX(0),DKXMA(0);

input:length(10);
MID=(close*3+open+high+low)/6;
variable:r1(0);
midsum=0;

for r1=0 to 19 begin
midsum=(20-r1)*mid[r1]+midsum;
end;

DKX=midsum/210;
dkxma=average(dkx,length);

plot1(close,"收盤價");
plot2(dkxma,"dkx的移動平均線");