Author Archives: 發財橘子

以前寫情書的時候，我們常說: 妳的過去我來不及參與，但妳的未來一定有我。

作為一個操作者，我們對那些來不及上車的強勢股，也往往有這樣的心情，

這樣的心情，如果用波浪理論來解釋，那就是在初昇段來不及參與之後，希望在主昇段發動前夕，來得及坐上車。

為了尋找這一類的股票，我試著寫一個腳本，這個腳本有三個步驟

1.尋找特定日期以來漲幅最大，走勢最強的股票

2.這樣的股票，從這段時間以來的最高點到前一日的收盤，已修正一定的幅度

3.今天盤中該個股明顯走強。

在要寫這個腳本時，首先得先找出某特定日到最新的收盤價，一共是幾根Bar。

公司同仁寫了一個函數來做這件事，他把這個函數稱之為

getbaroffset

這個函數的腳本如下:

Input: target(numeric);

if barfreq <> "D" AND barfreq <> "W" AND barfreq <> "M" then raiseruntimeerror("只支援日/週/月頻率");

variable: i(0);
variable: target_ym(0), date_ym(0);

if barfreq = "D" then
begin
 if target >= date then
 begin
 GetBarOffset = 0;
 return;
 end;
 i = 1;
 GetBarOffset = 1;
 while i < currentbar
 begin
 if date[i] <= target then return;
 i = i + 1; 
 GetBarOffset = GetBarOffset + 1;
 end;
end;

if barfreq = "W" then
begin 
 target_ym = year(target) * 100 + weekofyear(target);
 if dayofweek(target) = 0 then target_ym = target_ym - 1;
 
 GetBarOffset = 0;
 i = 0;
 while i < currentbar
 begin
 date_ym = year(date[i]) * 100 + weekofyear(date[i]);
 if dayofweek(date[i]) = 0 then date_ym = date_ym - 1;
 
 if date_ym <= target_ym then return;
 i = i + 1;
 GetBarOffset = GetBarOffset + 1;
 end; 
end;

if barfreq = "M" then
begin
 target_ym = year(target) * 100 + month(target);
 
 GetBarOffset = 0;
 i = 0;
 while i < currentbar
 begin
 date_ym = year(date[i]) * 100 + month(date[i]);
 
 if date_ym <= target_ym then return;
 i = i + 1;
 GetBarOffset = GetBarOffset + 1;
 end; 
end;

這個函數是只要輸入一個日期，就會回傳從現在到該特定日期共隔了幾根Bar。

如果今天是2015年10月15日，那如果我們寫value1=getbaroffset(20151014);

那代表是前一根bar，所以value1=1;

有了這個函數，我就來寫出上面所提到的這個腳本

input: stardate(20150824);
input:ratio(30);
input:ratio1(7);
input:ratio2(2);
setinputname(1,"輸入上漲起始日");
setinputname(2,"輸入上漲最低幅度");
setinputname(3,"輸入最小拉回幅度");
setinputname(4,"今日最低漲幅");
value1=getbaroffset(stardate);//找出輸入的日期是在第幾根bar
value2=highest(high[1],value1+1);//找出這一波的最高點

condition1=false;
condition2=false;

if value2>=close[value1]*(1+ratio/100)//計算波段漲幅有沒有符合要求
then condition1=true;

if value2>=close[1]*(1+ratio1/100)//計算拉回的幅度夠不夠要求
then condition2=true;

if nthhighestbar(1,high,10)>=5//從最高點到今天超過五根bar
then begin
if condition1 and condition2 and close>=close[1]*(1+ratio2/100)
then ret=1;
end;

在解釋這個腳本之前，我們先來看一下大盤最近的走勢

所以我上面寫的這個腳本，就是找出符合下面四個條件的股票

1.從8/24日以來，到最高點漲幅超過30%的股票

2.從最高點到前一個交易日的低點修正幅度超過7%

3.今天收盤比前一天收盤漲超過2%

4.從高點拉回整理超過五天。

這樣的腳本要尋找的，就是整理結束後的強勢股。

下面這張圖就是這個腳本今天跑出來的股票

當然不是每檔股票都會在初昇段之後就一定有主昇段，也不見得每檔股票都是休息了幾天後就開始再往上攻，不過這個策略的好處是，對於那些從特定日期以來走勢很強的股票，一旦整理結束，我們在第一時間就會收到電腦的通知，這樣的好處是我不必一直盯著強勢股等拉回結束。

這個腳本可以名列我的私房腳本第二名，介紹給大家，至於日期及漲幅，拉回幅度，這些參數就請大家自己調整囉!

我們透過技術分析指標建構交易策略時，最大的困難在於，當趨勢指標通知我們出現買進訊號時，往往只是盤整過程中的一次假的警報。

我們以移動平均線出現黃金交叉為例，當短天期移動平均突破長天期移動平均時，僅能代表近日的股價走勢平均下來終於高於比較長期的平均值，並不代表接下來股價就會出現明顯的漲勢。

這樣的情況讓我們在透過趨勢指標撰寫交易策略時，往往會有買進訊號過多，過濫的情況，如果我們把這樣的策略直接拿下去交易，極可能繳了大量的手續費及交易稅，而沒有賺到什麼錢。

於是，我們試著從歷史的經驗中，尋找當一檔股票出現明顯的波動方向時，往往伴隨著什麼樣的跡象，然後看看這些跡象，在趨勢指標出現買進訊號時，有沒有同步出現，如果有，代表這個趨勢改變的訊號，成功的機率大增。

我們可以試著把這些跡象集合起來，然後做出一個趨勢檢定器，用這個檢定器來過濾那些可能的假訊號。

例如老市場常說，當MACD黃金交叉時，如果伴隨著成交量突破10日均量，那就代表趨勢是真的，這裡的成交量突破10日均量，就是一個趨勢檢定器。

這些年從我累積的看盤經驗裡，通常當一檔股票技術指標如果出現買進訊號時，我會同步check以下幾件事，然後再來判斷這個訊號是不是玩真的

1.總成交筆數有沒有增加?  有就代表交投變熱絡了，表示市場參與者變多了。

2.佔全市場總成交量的比重是不是在增加?  有增加才代表不是因為盤好才出量。

3.外盤的佔比是否增加? 外盤代表的是追價的意願，追價意願提高是上漲的重要動力。

4.主力是否買超?  籌碼被收集而不是被發散，是行情啟動的基本要件

5.波動幅度是否變大? 一灘死水的突破通常是假突破。

6.開盤委買有沒有增加? 如果增加代表新的買盤在進駐中。

於是我寫了一個腳本，在這腳本中我應用上面的這六個面象，做出一個計分器，如果每個面象近兩個交易日有任一天有明顯比以往平均值突出的數字，就加一分，然後如果總得分超過4分，代表通過這個趨勢檢定器的檢定。

input:Length(10);

input:ratio(20);
input:cn(4);

setinputname(1,"移動平均天數");
setinputname(2,"超出均值比率");
setinputname(3,"最低符合條件數");
variable:count(0);
value1=GetField("總成交次數","D");
value2=GetField("佔全市場成交量比","D");
value3=GetField("內外盤比","D");
value4=GetField("外盤均量","D");
value5=GetField("主力買賣超張數","D");
value6=GetField("真實範圍波幅","D");
value7=GetField("開盤委買","D");
count=0;
if countif(value1 >=average(value1,length)*(1+ratio/100),2)>0
then count=count+1;

if countif(value2 >=average(value2,length)*(1+ratio/100),2)>0
then count=count+1;

if countif(value3 >=average(value3,length)*(1+ratio/100),2)>0
then count=count+1;

if countif(value4 >=average(value4,length)*(1+ratio/100),2)>0
then count=count+1;

if countif(value5>0,2)>0
then count=count+1;

if countif(value6 >=average(value6,length)*(1+ratio/100),2)>0
then count=count+1;

if countif(value7 >=average(value7,length)*(1+ratio/100),2)>0
then count=count+1;

if countif(volume >=average(volume,length)*(1+ratio/100),3)>0
then count=count+1;

if count>cn
then ret=1;

outputfield1(count);
setoutputname1("檢定值");

透過這個檢定器，我們可以過濾掉不少的假買進訊號

舉個例子

如果我們用昨天的收盤價來跑以下這個腳本

input:Length(20); //"計算期間"

LinearReg(close, Length, 0, value1, value2, value3, value4);
//做收盤價20天線性回歸
{value1:斜率,value4:預期值}
value5=rsquare(close,value4,20);//算收盤價與線性回歸值的R平方
if value1>0 and value5>0.2
then ret=1;

這個腳本跑出來的股票是屬於那種近20天股價呈現上昇趨勢的股票，結果符合上述腳本條件的股票共有286檔，這286檔今天盤中在平盤以上的共有128檔。

但如果加了趨勢檢定器，就如下圖，符合兩個條件的只剩109檔

而這109檔今天在大盤下跌46點時，還維持在平盤上的，有69檔。

我們在寫趨勢型策略時，最怕的就是把no trend的歸成up trend，今天跟大家介紹這個趨勢檢查表，大家可以根據自己的經驗，調整內容，把那些no trend的通通都濾掉。

台股能不能繼續漲? 如果可以，會是什麼股票領漲?

要回答這個問題，我們先來對市場的多空架構做個定義

如果根據這樣的定義，那麼加權指數已經即將正式翻多

如果從細產業來看，我們會發現，這當中塑化原料及不鏽鋼兩大族群是衝的最快的兩類產業，他們的指數分別在九月中旬及下旬就領先翻多。

為了很快的了解到底目前有那些股票位於這六階段不同的位置，我寫了一個腳本如下: 我特別濾掉那些股價不到10元，成交量不到1000張的股票，

input:status(1);
setinputname(1,"1:復甦期，2:收集期，3:多頭，4:警示期，5:發散期，6:空頭");
variable:m20(0),m60(0),message("0"),userchoice("0");
m20=average(close,20);
m60=average(close,60);
if close > m20 and c< m60 and m20<m60
then message="復甦期"
else
if close > m20 and c> m60 and m20<m60
then message="收集期"
else
if close > m20 and c> m60 and m20 > m60
then message="多頭"
else
if close < m20 and c>m60 and m20>m60
then message="警示期"
else
if close < m20 and c<m60 and m20>m60
then message="發散期"
else
if close < m20 and c<m60 and m20<m60
then message="空頭";

switch(status)
begin
case=1 :
userchoice="復甦期";
case=2 :
userchoice="收集期";
case=3 :
userchoice="多頭";
case=4 :
userchoice="警示期";
case=5 :
userchoice="發散期";
case=6 :
userchoice="空頭";
end;

if message=userchoice
and volume>1000 and close>10
then ret=1;
outputfield1(message);
setoutputname1("今日訊號");
outputfield2(message[1]);
setoutputname2("昨日訊號");
outputfield3(message[2]);
setoutputname3("前日訊號");

根據這個腳本，我選出的多頭的股票如下圖

空頭的股票如下圖

我們從多頭及空頭架構的股票，可以發現，受惠於台幣貶值的外銷股，景氣到底的塑化股，以及跌深且旺季到的電子股，目前是處於多頭走勢，金融股，航空股及部份先前比較強的個股則處於空頭走勢。

從這樣的架構來看，台幣續貶力道，電子旺季持續力，美國需求，以及全球景氣循環股的續航力(油價及工業金屬)，會是這個盤能持續多頭多久的主要指標。

除了用這一套方法來研判大盤漲昇架構之外，我稍稍更改一下腳本如下:

variable:m20(0),m60(0),message("0") ;
m20=average(close,20);
m60=average(close,60);
if close > m20 and c< m60 and m20<m60
then message="復甦期"
else
if close > m20 and c> m60 and m20<m60
then message="收集期"
else
if close > m20 and c> m60 and m20 > m60
then message="多頭"
else
if close < m20 and c>m60 and m20>m60
then message="警示期"
else
if close < m20 and c<m60 and m20>m60
then message="發散期"
else
if close < m20 and c<m60 and m20<m60
then message="空頭";

if message<>message[1]
and volume>500 and close>10
then ret=1;
outputfield1(message);
setoutputname1("今日訊號");
outputfield2(message[1]);
setoutputname2("昨日訊號");
outputfield3(message[2]);
setoutputname3("前日訊號");

這個腳本可以找出最近一日訊號跟前一日不同的股票，以下幾張圖就是根據上述的腳本跑出來的，有的變好，有的變壞，加減參考囉。

市場上有非常多的技術指標，學都學不完，但如果大家用的武器都一樣，總覺得很難能夠見人所未見，賺人所未賺，特別是有時候就是會有靈光乍現，電光火石的那一刻，當下如果能把靈感化為交易的策略，這快樂是我輩程式交易者，千金難換之快樂也。 容我舉個例子，跟大家分享這樣的快樂。

昨天同事來跟我借K線的書，我聊到其實有不少指標是本著K線的精神發明出來的。 我一直以來的體會是，每一根的K線都是那段時間多空爭戰的痕跡，

以前一根K棒收盤價為基點，所能測到的最高與最低點，就是當日多空雙方角力的最大範圍，在技術分析上我們稱之為真實區間

那麼在這樣的多空角力區間裡，我們怎麼知道多方與空方的力道各是多大呢?
我們常用的DMI指標，他的發明者是這麼計算的

他認為如果今天的高點比前一天高點多出來的部份就是正的向上力量，今天的低點比前一天低點低的部份就是向下的力量。

然後它拿這兩股力量去相比，那邊強，另一邊就只能以零計算，然後再去跟這樣的力量跟真實區間相除，看向上的力量佔真實波動區間的比例是多少

// DirectionMovement function (for DMI相關指標)
// Input: length
// Return: pdi_value(+di), ndi_value(-di), adx_value(adx)
//
input:
length(numericsimple),
pdi_value(numericref),
ndi_value(numericref),
adx_value(numericref);

variable:
padm(0), nadm(0), radx(0),
atr(0), pdm(0), ndm(0), tr(0),
dValue0(0), dValue1(0), dx(0),
idx(0);

if currentbar = 1 then
begin
padm = close / 10000;
nadm = padm;
atr = padm * 5;
radx = 20;
end
else
begin
pdm = maxlist(High - High[1], 0);
ndm = maxlist(Low[1] - Low, 0);

if pdm < ndm then
pdm = 0
else
begin
if pdm > ndm then
ndm = 0
else
begin
pdm = 0;
ndm = 0;
end;
end;

if Close[1] > High then
tr = Close[1] - Low
else
begin
if Close[1] < Low then
tr = High - Close[1]
else
tr = High - Low;
end;

padm = padm[1] + (pdm - padm[1]) / length;
nadm = nadm[1] + (ndm - nadm[1]) / length;
atr = atr[1] + (tr - atr[1]) / length;

dValue0 = 100 * padm / atr;
dValue1 = 100 * nadm / atr;

if dValue0 + dValue1 <> 0 then
dx = AbsValue(100 * (dValue0 - dValue1) / (dValue0 + dValue1));

radx = radx[1] + (dx - radx[1]) / length;
end;

pdi_value = dValue0;
ndi_value = dValue1;
adx_value = radx;

上面的程式碼就是DMI的計算過程

但我對這個指標有個想法，每天都有向上的力量跟向下的力量，不能因為其中一股力量大於另一股，就把另一邊計算為零，兩邊的力量應該要都被計算到，然後看那一邊的力量比較大

所以我就寫了以下的腳本:

input:sd(5);
input:ld(20);

setinputname(1,"短天期");
setinputname(2,"長天期");

variable:h1(0),l1(0),nf(0),snf(0),lnf(0),dd(0);

H1=HIGH-HIGH[1];
L1=LOW-LOW[1];

if truerange<>0
then
begin
NF=(H1+L1)/truerange;
SNF=average(NF,sd);
lnf=average(nf,ld);
dd=snf-lnf;
end;
plot1(dd,"多空淨力");

我去計算一檔股票每天多空角力的差距，佔真實波動區間的比重，然後看看短天期平均跟長天期平均之間的差。

以下這張圖就是我拿這個指標來畫在加權指數上的對應圖

這樣的指標，比起K線圖，更清楚地可以判斷現在是該站在多方還是空方。

上述的過程，是一個一步一步發展自訂指標的過程，我們可以透過這樣的過程，逐漸完備我們對一檔股票的多空判斷體系，當我們透過一連串自訂的指標來研判一檔股票的多空方向時，其實就像是透過多樣的儀器來做身體檢查，當我們發展出愈多愈觀察細微的健康檢查儀器，我們對於一檔股票的多空方向，就會有更高的掌握度。

以上是這些日子以來，我使用XS發展各種自訂指標的小小心得

野人獻曝，祝大家找到自己的股票多空檢查體系。