Author Archives: 發財橘子

我們看到很多的技術指標，它的計算基礎都建立在單支K棒開，高，低，收的相互關係上，甚至不少只用到收盤價。過於受限於電腦的運算能力，這樣的作法可以理解，現如今進入雲端運算時代，我們不妨用更週延的思維，來找出多空的角力痕跡，今天想用兩根K棒開，高，低，收合計八個價位的運算，來跟大家介紹不同思維的交易策略。

常常有人說，投資像推理，那麼交易的軌跡就像是推理所需要的跡證，一根K棒是四個點， 兩根K棒是八個點，從兩根K棒可以收集到的多空角力跡證比一根K棒要多很多。

我試著把兩根K棒可以拿來運算的數值整理了一下，分成八類，如下圖

其中前四個是多空力道的綜合，後面四個分別代表多頭與空頭的力量

根據這樣的分類，我寫了一個自訂指標的腳本，計算每檔商品的多空力道差距及多頭與空頭各自力量的消長。

array:k[22](0);
if close<>0
then begin
//最近一日與前一日的多空力道總差額
k[1]=(open-open[1])/close;
k[2]=(high-high[1])/close;
k[3]=(low-low[1])/close;
k[4]=(close-close[1])/close;

//當日
k[6]=(high-close)/close;
k[7]=(high-open)/close;
k[8]=(open-low)/close;
k[9]=(close-open)/close;
k[10]=(close-low)/close;
k[11]=(open-high[1])/close;
k[12]=(open-low[1])/close;
k[13]=(open-close[1])/close;
k[14]=(high-open[1])/close;
k[15]=(high-low[1])/close;
k[16]=(high-close[1])/close;
k[17]=(low-open[1])/close;
k[18]=(low-high[1])/close;
k[19]=(low-close[1])/close;
k[20]=(close-open[1])/close;
k[21]=(close-high[1])/close;
k[22]=(close-low[1])/close;
end;

array: v1[8](0);
v1[1]=k[1]+k[11]+k[12]+k[13];//隔日開盤多空總力道
v1[2]=k[1]+k[2]+k[3]+k[4];//隔日多空總力道
v1[3]=k[20]+k[21]+k[22];//隔日收盤多空結果
v1[4]=k[9]+k[10]-k[6];//當日收盤多空結果
v1[5]=k[14]+k[15]+k[16];//多頭最大力量
v1[6]=(k[17]+k[18]+k[19])*-1;//空頭最大力量
v1[7]=k[7]+k[9]+k[10];//當日多頭最大力量
v1[8]=k[6]+k[8]-k[10];//當日空頭最大力量

value1=v1[1]+v1[2]+v1[3]+v1[4];
value2=v1[5]+v1[7];
value3=v1[6]+v1[8];
plot1(average(value1,5),"多空淨力");
plot2(average(value2,5),"多頭總力");
plot3(average(value3,5),"空頭總力");

這個腳本可以同時衡量多空力道的差額及多頭與空頭各自的力量

用在加權指數上可以畫出的圖形就如下圖

我們可以從這張圖上看到幾個可以形成交易決策的原則

1.當多空淨力在 0以上是基本上是多頭市場，0以下是空頭市場。

2.當多頭總力與空頭總力糾結時是盤整格局

3.當多頭總力與空頭總力的差距愈來愈大時代表一個多頭或空頭的趨勢被確認

4.多空淨力差距過大時代表市場一面倒，屬於超買或超賣的情況，短線有拉回或反彈的機會

根據這些跡證，我們就可以訂出一些更精準的交易策略

我們在設定個股的買進策略時，有時候會踫到假的訊號，例如震盪型指標踫到盤整時，就容易出現假訊號，就算嚴格執行停損，還是會因為過度交易，浪費交易成本而必影響獲利，今天來跟大家考論一個概念，如果我在寫一個股性轉變的濾網，當策略出現買進訊號時，透過這個濾網來觀察股性是否真的有明顯改變，只有真的有明顯改變時才觸發訊號，這麼做應該可以避免過度交易的情況

我曾經跟大家分享過我有十二個衡量股性的標準

我試著用計分卡的方式寫了一個衡量股性的腳本如下:

input:day(20);
input:ratio(10);
var:count(0),x(0);
value1=GetField("總成交次數","D");
value2=average(value1,day);
value3=GetField("強弱指標");
value5=GetField("外盤均量");
value6=average(value5,day);
value7=GetField("主動買力");
value8=average(value7,day);
value9=GetField("開盤委買");
value10=average(value9,day);
value11=GetField("資金流向");
value13=countif(value3>1,day);
value14=average(value13,day);//比大盤強天數
value16=GetField("法人買張");

count=0;
if value1>value2*(1+ratio/100)
then count=count+1;
if value13>value14*(1+ratio/100)//比大盤強的天數
then count=count+1;
if value5>value6*(1+ratio/100)
then count=count+1;
if value7>value8*(1+ratio/100)
then count=count+1;
if value9>value10*(1+ratio/100)
then count=count+1;
if truerange> average(truerange,20)//真實波動區間
then count=count+1;
if truerange<>0
then begin
if close<=open
then
value15=(close-low)/truerange*100
else
value15=(open-low)/truerange*100;//計算承接的力道
end;
if value15>average(value15,day)*(1+ratio/100)
then count=count+1;
if volume<>0
then value17=value16/volume*100;//法人買張佔成交量比例

if value17>average(value17,10)*(1+ratio/100)
then count=count+1;

if value11>average(value11,10)*(1+ratio/100)
then count=count+1;
x=0;
value18=summationif(close>=close[1]*1.02,x,5);
if value18>=2 
then count=count+1;//N日來漲幅較大的天數



value19=GetField("融資買進張數");
value20=GetField("融券買進張數");
value21=(value19+value20);
value22=average(value21,day);
if value21<value22*0.9 //散戶作多指標
then count=count+1;

plot1(average(count,3),"股性綜合分數指標");
plot2(average(count,day),"移動平均");

從以下幾檔這個月逆勢上漲的股票，我們可以發現，股票有大行情時，股性會有明顯的變化

各位不妨以這個例子為基礎，發展各自不同的股性過濾腳本，這樣就可以減少過度交易及盤整時出現假訊號的機率

類股輪動操作法的邏輯很簡單，找到現在表現最強的產業，投資其龍頭股。以前這種操作很難把它自動化，更別說去回溯測試這個策略的勝率及績效了，我試著把它程式化，算是拋磚引玉，希望各位可以發展出更強大的類股輪動操作策略。

我的演算過程分成兩部份，一部份是找出走勢比加權指數強的產業指數，另一部份則是找出各細產業中股價最活潑的個股

在第一部份，我的作法還是計算各產業指數與大盤相除後的BB值，這個值突破BB值上限就是表現異常強勢，以塑化原料為例就像下面這張圖

第二部份的作法則是先找出貝他最高的股票

我訂了兩個條件

1.貝他值大於1

2.月成交量平均大於5000張

結果選出了433檔股票。

接下來我就開始把這433檔股票，拿去跑下面我寫的這個腳本

這個腳本的概念就是先把這433檔的相關細產業指數拿去跟大盤比強度，強度異常時，就觸發該產業在這433檔中所屬的股票。

我從這433檔股票中，挑出18檔股票，這些股票分別是其所屬產業中的龍頭股，然後請了公司的高手高手高高手寫了以下的指標

input: Length(20); SetInputName(1, "布林通道天數");
input: BandRange(2);SetInputName(2, "上下寬度");
input: MALength(10);SetInputName(3, "MA天期");
array:
ValueArray[18](0),
ratioarray[18](0),
uparray[18](0),
dnarray[18](0);
var:x(0);
var:si(0);// 商品所在的產業
if symbol="1101.TW" then si=1;
if symbol="1305.TW" then si=2;
if symbol="1452.TW" then si=3;
if symbol="1536.TW" then si=4;
if symbol="1460.TW" then si=5;
if symbol="1476.TW" then si=6;
if symbol="6269.TW" then si=7;
if symbol="2031.TW" then si=8;
if symbol="2014.TW" then si=9;
if symbol="2393.TW" then si=10;
if symbol="2615.TW" then si=11;
if symbol="2409.TW" then si=12;
if symbol="2882.TW" then si=13;
if symbol="6005.TW" then si=14;
if symbol="2606.TW" then si=15;
if symbol="3044.TW" then si=16;
if symbol="6244.TW" then si=17;
if symbol="9914.TW" then si=18;
if si = 0 then return;
valuearray[1]=GetSymbolField("I011010.TW","收盤價");//水泥
valuearray[2]=GetSymbolField("I013010.TW","收盤價");//塑化原料
valuearray[3]=GetSymbolField("I014010.TW","收盤價");//加工絲
valuearray[4]=GetSymbolField("I022020.TW","收盤價");//汽車零組件
valuearray[5]=GetSymbolField("I014040.TW","收盤價");//織布
valuearray[6]=GetSymbolField("I014030.TW","收盤價");//成衣
valuearray[7]=GetSymbolField("I023320.TW","收盤價");//軟板
valuearray[8]=GetSymbolField("I020010.TW","收盤價");//不銹鋼
valuearray[9]=GetSymbolField("I020020.TW","收盤價");//平板鋼
valuearray[10]=GetSymbolField("I023060.TW","收盤價");//LED
valuearray[11]=GetSymbolField("I026020.TW","收盤價");//貨櫃航運
valuearray[12]=GetSymbolField("I023080.TW","收盤價");//面板
valuearray[13]=GetSymbolField("I028010.TW","收盤價");//金控
valuearray[14]=GetSymbolField("I028030.TW","收盤價");//證券
valuearray[15]=GetSymbolField("I026030.TW","收盤價");//散裝航運
valuearray[16]=GetSymbolField("I023230.TW","收盤價");//印刷電路板
valuearray[17]=GetSymbolField("I023130.TW","收盤價");//太陽能
valuearray[18]=GetSymbolField("I099040.TW","收盤價");//自行車

value1=GetSymbolField("TSE.TW","收盤價");
ratioarray[si]=valuearray[si]/value1;
uparray[si]=bollingerband(ratioarray[si],length,bandrange);
dnarray[si]=bollingerband(ratioarray[si],length,-1*bandrange);
plot1(uparray[si], "UB");
plot2(dnarray[si], "DB");
plot3(ratioarray[si], "Ratio");
if ratioarray[si] cross over uparray[si] then
plot4(1, "穿越")
else
noplot(4);

這個指標如果畫成圖就像下圖

這個腳本把plot4改成ret=1就成了警示腳本

下圖就是過去三年的回測報告

績效還真的不錯。

透過這個腳本，未來這十八檔股票所屬的細產業如果比大盤表現異常突出，系統會針對該檔股票觸發信號

以上就是所謂sector trade的一種基本類型，希望可以激發大家更多的靈感

在金融情勢詭譎多變的時候，我們很難判斷接下來的股市會怎麼走，但如果我們很清楚知道，在同一行業裡的某A股票，基本面長期表現會比某B股票好，這時候我們就可以作多A股票，放空B股票，不管大盤漲還跌，都可以靠這樣的操作賺到錢，這樣的操作就稱之為多空交易(long-short trading)

舉個例子，大家都知道台積電跟聯電長期以來競爭力差很大，但以往聯電的股性有時候會突然活潑了起來，短期不見得表現比台積電差，這時候我們可以把兩家公司的總市值相除，然後再取兩個長短天期不同的移動平均線，這樣我們就可以觀察兩家公司總市值的長期趨勢變化，也可以透過長短天期移動平均線的黃金交叉及死亡交叉，來決定多空交易的進場點及平倉時點。

根據上述的精神，我寫了一個畫圖的腳本如下:

input:period1(4,"短期別");
input:period2(12,"長期別");
setbackbar(12);
settotalbar(600);
value1=GetSymbolField("2303.tw","總市值");
value2=GetField("總市值");
value3=value1/value2;
value4=average(value3,period1);
value5=average(value3,period2);
plot1(value4);
plot2(value5);

使用這個腳本，用週線的頻率，可以畫出下面這張圖

從這張圖，我們就可以很清楚的看到如果我們在2014年八月四日那一週開始作多台積電，放空聯電，到目前為止，都還沒有出現平倉的訊號，而到目前為止的投資報酬率是三成左右，如果我們用個股期貨來操作，報酬率就會因為槓桿而變得很驚人。

我想大家一定會說我在看圖說故事，台積電與聯電的例子大家都太瞭解了，應該要提供一些新的多空交易標的。

在這個部落格，我一貫不報明牌，但我很喜歡分享我的交易經驗及思考的方式，所以，我提出幾個多空交易的配對思考方向，供大家作參考

方向一: 尋找因為某事件或議題，造成一個長期趨勢，這時就可以把因此趨勢而會受益與受害的公司作配對

這個例子最明顯的就是統一跟味全

另外像是台幣升值時，作多食品股，作空外銷電子股

方向二，當某原料長期上漲時，作多生產該原物料的上游，作空下游，相反的，某原料價格長期下跌時，作多下游，作空上游，不過必須留意的是下游是否有高價庫存待消化，如果有，那轉折點會在原料下跌趨勢一段時間之後

方向三，同一產業競爭力有明顯差異的兩家公司，前面提到的台積電與聯電是一個明顯的例子，以前友達跟華映也是很好的多空交易標的，台郡跟嘉聯益是另一個明顯的例子

方向四  爭奪特定有限市場(如國內市場)而明顯分出勝負時

這種最有名的就是國泰金與新光金

隨著個股期貨以及借券等措施的開放，也隨著XS即將支援跨商品功能，我們愈來愈有機會透過XS尋找及實踐各種不同類型的多空交易。如此一來，我們可以專心研究同產業或特定議題趨勢下的受益與受害公司，並且透過一多一空的方式，進行多空交易，如此一來，我們就不必理會國際金融市場對於台股的多空衝擊，只要專注在企業競爭力的研究上。

隨著開始使用XS寫交易策略的朋友們愈來愈多，我們愈來愈常被求救，問題看多了，歸納整理後，我寫了一個撰寫交易策略的SOP，我認為在撰寫交易腳本時，有四大步驟，嚴謹且按步就班地作好每個步驟，應該可以協助我們完成交易策略的撰寫。

這四個步驟如下圖

茲分項說明之

一，準備數據

程式交易語法跟其他如C++，Java等不同之處，是在於它的目標很明確~透過大量金融數據的運算，作成交易決策，所以在一個程式交易腳本中，最基本的課題是: “要拿那些金融數據進來運算?”

每個腳本，都像一道食譜，每個食譜，都會要我們先準備食材，腳本的食材，就是我們要拿下去運算的每個元素，在XS的腳本中，這些要拿來加減乘除作運算的元素，可以歸類為以下幾種

1. 即時行情的數據。包括單量，當日漲幅，內盤量，外盤量，五檔委買賣的價與委託量等等，我們可以用 Getquote的語法把它們拉出來使用。

2. 盤後數據。包括法人進出，資券變化，主力進出等等數據，我們用Getfield的語法把這些欄位拿到腳本中來使用

3. 回傳值。開高低收成交量等語法中最基本的元素，在以K棒為基礎的架構裡，我們可以用Close[n]之類的語法，把K棒中 的每一個被存下來的值拿來運算。

4. 參數。為了更改參數方便而由使用者以INPUT的語法所設定的參數，也是可以被拿來腳本中作運算。

5. 變數。為了運算方便，由使用者自行宣告的變數，也是腳本中常見的元素。

6. 常數。有的時候，就是會運用到簡單的阿拉伯數字，或是True及false這兩個布林值，這些都是腳本運算中常用的元素。當我們要要撰寫一個腳本時，就像食譜要先準備的食材一樣，我們得先決定要用上述六大類裡的那些元素，這個決定的工作，就像是煮一道菜之前，先把相關的食材從冰箱裡取出來。

決定好之後，接下來要做的是事情有兩個

第一個是宣告: 我們先透過宣告的方式，把要用的變數及參數先準備好，我們為它們取名字，設初始值。

第二個是指定: 然後接下來我們用getquote及getfield的語法，把盤後資料及盤中資料指定到特定的某個變數

二，建構演算

以上的這兩個步驟，就好像是煮菜之前的備料工作。備完料，接下來就是建構演算的機制，在這當中，若是有需要，會使用到系統或自訂的 函數。    大家可以透過先前學會的流程控，以及各種函數，透過數學及邏輯運算，完成各種運算。

這部份主要是看個人的功力，只能多看多寫，多看別人寫過的好語法。

三，設定輸出條件

接下來，就是建立輸出條件，我們用if ……..then  ret=1; 來指定策略雷達的觸發條件，以及選股的符合條件，用if………then plot1…;來輸出自訂指標。

我與個例子來說明以上的流程

我們希望電腦在個股符合下列三個條件時通知我們，

1.    十日法人買超的移動平均超過1000張
2.    當日外盤量佔成交量超過五成
3.    當日股價比前一日上漲

那麼我們可以寫下一個腳本如下:

各位可以看到，我們依以下的步驟在完成一個警示腳本

步驟一: 宣告參數

步驟二: 宣告變數

步驟三: 取得盤後資料

步驟四: 取得即時數據

步驟五: 建構運算關係

步驟六: 設立觸發，畫指標或確認 函數的敘述式

當然在實作上，步驟一到步驟五的任何一項 ，都可能因為沒有用到相關數據而被省略，最簡單的警示腳本如if close=high then ret=1;就只有步驟六而已。

但如果大家記得這六個基本的步驟，應該可以很快的把各式各樣的數據，同步放在一個警示腳本中來使用。

 四，編譯與勘誤

接下來的編譯及勘誤，是另一個重點，很多朋友就算是提供了中文的勘誤，還是無法自行找出程式碼的問題之所在，所以我把大家常見的程式上的疏誤，以及在勘誤時系統會出現的訊息做了一個對照表如下，供大家參考。

XS的勘誤方式，跟其他的IDE類似，在使用者按下編譯按鈕之後，如果程式有Bug，會在訊息視窗中，以表格的方式來呈現錯誤的地方，其呈現方式如下:

根據我自己使用的經驗，User通常會出現的錯誤，以及XS編輯器對應會出現的勘誤訊息，大致有以下幾類。

 文字上的小失誤

 流程的錯誤

 函數的錯誤使用

 用到不該用的欄位

 數值與布林值使用上的混淆

 宣告參數時容易發生的失誤

 變數使用上的錯誤

 陣列使用上出現的疏誤

當編譯後出現錯誤訊息後，即可根據上面表格的說明，找出錯誤的原因並且加上修正，如此一來可以縮短程式開發的速度，並且讓程式可以忠實呈現使用者的想法。

魚骨圖又被稱為特性要因圖，是經理人們常用的工具，在要解決一個問題時，透過魚骨圖的方式，列出會影響結果的每個重要環節，然後透過腦力激盪，找出每個重要環節的核心要素。在進行投資決策時，魚骨圖也是一個蠻好用的工具，可以讓我們找出真正會影響股價波動的要素。

以下圖為例

我每天都會把漲幅較大，且有一定成交量的股票，拿出來研究一翻，然後我歸納出這些股票常有的共同特徵

1.線型上在上昇趨勢中

2.籌碼是穩定的

3.今天開盤就明顯比較強

所以我就試著以魚骨圖的方式，列出要符合上述三個特徵，它們各別的要素是什麼，然後把這些要素寫成腳本

//先準備需要被拿來運算的資料
value1=GetField("法人買賣超張數");
value2=GetField("主力買賣超張數");
value3=GetField("融券增減張數");
value4=q_BoughtLotsAtOpen;//開盤委買張數
value5=q_SoldLotsAtOpen;//開盤委賣張數

//先宣告魚骨圖的魚骨數並先為false
condition1=false;
condition2=false;
condition3=false;
//描述魚骨在什麼情況下由false變成true
if value1[1]>0 and value2[1]>0 and value3[1]>0 
then condition1=true; //符合籌碼穩定的條件
//===============MACD =================================
input: FastLength(12,"DIF短期期數"), SlowLength(26,"DIF長期期數");
input: MACDLength(9,"MACD期數");
variable: difValue(0), macdValue(0), oscValue(0);
MACD(weightedclose(), FastLength, SlowLength, MACDLength, difValue, macdValue, oscValue);

if oscValue > 0 and average(close,5)>average(close,20)
then condition2=true; //符合上昇趨勢的條件

if open > close[1]*1.015 and value4>highest(value4[1],20) or value4-value5>200
then condition3=true; //符合開盤走強

if condition1 and condition2 and condition3
then ret=1;

這個腳本的結構，主要是用condition1………到conditionN來界定投資決策的重要環節，然後列出所有該環節底下的核心要素，並寫成條件式，然後再透過關係運算子and或是or來建構核心要素與該環節的成立要件，而投資決策的形成，必須是所有環節都成立。

在語法上，它的架構就如下圖

在擬定交易策略時，針對當沖，隔日沖，短線，波段等不同的交易方式，會影響績效的環節不會一樣，每個環節裡的核心要素也不一樣，我的研究方法是把不同交易方式裡成功的例子拿出來研究，尋找真正會影響績效的環節，然後再透過各種嚐試及回測，找出最能代表每個環節表現的核心要素，然後透過上述的語法結構，完成一個投資決策的腳本。各位不妨試著以類似的方法完成自己的交易決策魚骨圖，然後根據上面的語法範例完成自己的投資決策腳本。