最近盤比較震盪，來介紹一個屬於抄底型的選股策略~創百日新高但距低點不遠。這個策略是去尋找那些剛剛創百日來新高，而且離近二十日低點還沒有太遠的股票，這樣的選股策略，有還可接受的策略，優點是，因為離低點不遠，所以風險相對較可接受。

這個選股策略的選股條件如下

請看一下右上方就是選股條件，其中的選股腳本如下

input:day(200,"計算區間");
input:day1(20,"短線漲幅計算區間");
input:percents(10,"距離區間最低點漲幅");

value1=lowest(close,day1-1);
if close=highest(close,day-1)
and value1*(1+percents/100)>=high
and high >= value1*1.05

and volume >= average(volume[1], 5)

then ret=1;

我拿這個選股策略去回測，停損停利都設為7%，回測的結果如下

勝率雖然不到六成，但MDD只有9%多，風險在可接受範圍。

每個人的交易風格不同，有人喜歡追強勢股，有的人喜歡挑剛開始起漲的股票，有的人愛藍籌碼，有的人愛低價轉機股，這個策略適合想追高但又怕風險太高的投資人，因為股價能創百日新高代表基本面可能有所變化，但股價離20日內的低點不遠，代表短期漲幅還沒有過大。

以下就是這策略近期挑到的股票

美股隊長操作秘笈這本書裡有介紹了一個叫作板塊輪動圖的工具，這個工具把產業板塊的輪動，分成四個不同的階段

從落後到改善到領先到轉差，形成一個循環。

一般來說，當一個產業從落後到改善，代表這個產業開始在築底，當從改善轉向領先，代表已變成市場主流，等到轉差時就差不多該獲利了結了

那要如何判斷現在是屬於四階段裡的那個階段呢，書上用的是一個叫作JDK RS的指標，以及其衍生出來的JDK RS動力指標。

由於我查了半天也找不到精確的計算公式，所以就自己試寫了一個

variable:JDKRS(0);
variable:JDKRSMTM(0);
VALUE1=(rateofchange(close,1)-rateofchange(getsymbolfield("TSE.TW", "close", "D"),1))/100;
JDKRS=AVERAGE((1+VALUE1)*100,14);
JDKRSMTM=momentum(JDKRS,10);

Plot1(JDKRS,"KDJRS");
plot2(JDKRSMTM,"KDJRSMTM");
plot3(100);

上面這個是指標的畫法

我把它跟細產業指標放在一起做成一個自訂頁面

這樣大家可能還看的不是很清楚，所以我另外寫了一個選股腳本

variable:JDKRS(0);
variable:JDKRSMTM(0);
VALUE1=(rateofchange(close,1)-rateofchange(getsymbolfield("TSE.TW", "close", "D"),1))/100;
JDKRS=AVERAGE((1+VALUE1)*100,14);
JDKRSMTM=momentum(JDKRS,10)*200;
variable:status("");
if JDKRS>=100 and JDKRSMTM>=0 then status="領先"
else
if JDKRS>=100 and JDKRSMTM<0 then status="轉差"
else
if JDKRS<100 and JDKRSMTM>=0 then status="改善"
else
if JDKRS<100 and JDKRSMTM<0 then status="落後";

if status[1]="改善"and status="領先" then ret=1;
outputfield(1,status,0,"今日狀態");
outputfield(2,status[1],0,"前一日狀態");

這樣跑出來的就是那些從改善進到領先的細產業，以昨天跑出來的結果為例

符合條件的就有筆電，變壓器及金融其他三個細產業

以上是我手作的板塊輪動圖，我也不知道這到底是不是真的是原始作者用的公式，算是起個頭，有興趣的朋友可以產生自己的產業輪動圖

今天來跟大家介紹一個偏價值型的交易策略，這個策略是用現在的本業獲利去推估公司的長期價值，然後當股價遠低於長期估值，且開始暴量起漲時，就進場。

這裡我用的選股腳本是去尋找過去五年獲利穩定的公司，用目前的營業利益，然後假設未來十年的營業利益年增率及折現用的利率，把未來十年每一年的本業獲利折現，然後加總後加上淨值，再看看這個數字跟目前股價的比值，如果比值低於一，那就代表股價被低估。

選股策略

variable: idx(0), t(0);
input:r1(3, "假設未來十年營業利益年成長率");
input:r2(2, "未來十年平均年利率");
input:r3(100, "未來獲利折現合計淨值與市價比");

// 計算未來10年的營業利益折現值

value1=GetField("營業利益","Y"); //單位:百萬
value2=GetField("最新股本"); //單位:億
value3=GetField("每股淨值(元)","y");

value11 = maxlist(GetField("營業利益","Y"),GetField("營業利益","Y")[1],GetField("營業利益","Y")[2],GetField("營業利益","Y")[3],GetField("營業利益","Y")[4]);
value12 = minlist(GetField("營業利益","Y"),GetField("營業利益","Y")[1],GetField("營業利益","Y")[2],GetField("營業利益","Y")[3],GetField("營業利益","Y")[4]);

if trueall(value1>0,5) and (value11-value12)/value11<0.5 then begin
t = 0;
for idx =1 to 10 begin
t = t + value1 * power(1+r1/100,idx)/power(1+r2/100,idx);
end;

// t=百萬,value2=億,換成每股
value5 = t / value2 / 100;
value6=close/(value3+value5);

if value6<r3/100
then ret=1;
end;

outputfield(1, value5, 2, "估算每股營業利益");
outputfield(2, value6, 1, "市價/淨值比", order := -1);

警示腳本

 Input: day(60,"日期區間");
Input: ratioLimit(14, "區間最大漲幅%");

Condition1 = H=highest(H,day);
//今日最高創區間最高價

Condition2 = V=highest(v,day);
//今日成交量創區間最大量

Condition3 = highest(H,day) < lowest(L,day)*(1 + ratioLimit*0.01);
//今日最高價距離區間最低價漲幅尚不大

if Condition1 And Condition2 And Condition3
then ret=1;

回測報告

以下是過去兩年及三年的回測報告，停損停利我都設7%

這個策略除了勝率不錯之外，MDD也夠低，自是一個低風險的交易策略

今天來跟大家介紹另一個籌碼面的交易策略： 投信動真格的。 這個策略的概念是，如果投信持續買一檔股票且累計超過一億台幣，而且這檔股票股價不到100元，然後股價也同時突破五日均線，代表這是一檔投信在用力追價大買的股票，過去幾年這樣的股票回測下來，超過七成的機率會賺錢。

這個策略近期的代表作就是鴻海

在10/29日鴻海就符合了這個策略的進場訊號

接下來跟大家分享相關的腳本及回測報告

選股策略

value1=GetField("投信買賣超","D");
if value1 <=0
then value2=0
else
value2=value2[1]+value1;
value3=close*value2/10;//單位:萬元

if value3 crosses over 10000
and close<100

then ret=1;

警示策略

input:period(5);
if close crosses over average(close,period)
then ret=1;

回測報告

這裡我們依然是7%停損停利，上面兩張分別是回測兩年及三年的回測報告，不管勝率還是年均報酬率，都十分迷人，唯一的缺點是，空頭市場投信認賠砍起股票時也是很粗殘的，所以這個策略在大空頭市場MDD蠻嚇人的。不過如果不是大空頭市場，這是一個還蠻不錯的交易策略。

有網友來函問到可否介紹一些籌碼相關的交易策略，原因是沒有讀過會計，覺得財務數據像天書一樣，但籌碼是比較容易理解的。那麼我先來跟大家介紹一個勝率快有七成的籌碼相關交易策略~ 地緣券商連三日買超且短期均線突破長期均線。

這個策略，是去尋找公司附近券商分公司，如果連續三日買超該公司股票都超過200張，而且三日均線突破十日均線，那就是一個進場訊號。

這裡用的是系統內建的地緣券商買賣超張數這個欄位，這裡所謂的地緣券商定義，是以個股總公司為圓心, 找出位在公司附近的券商分點, 預設的半徑為3公里 , 如果距離總公司小於3公里的券商分點家數超過30家, 距離改為1 KM, 反之, 若券商分點家數為0, 距離改為10 KM; 符合上述條件分點,扣除外資券商， 即列為此個股的地緣券商。

選股腳本

value1=GetField("地緣券商買賣超張數","D");
if trueall(value1>200,3)
then ret=1;

警示腳本

input: Shortlength(3); setinputname(1,"短期均線期數");
input: Longlength(10); setinputname(2,"長期均線期數");

settotalbar(8);
setbarback(maxlist(Shortlength,Longlength,6));

If Average(Close,Shortlength) crosses over Average(Close,Longlength) then Ret=1;

回測報告

上述的回測報告，停損停利都設7%，各位可以發現，這樣的交易策略，在空頭市場，MDD達到25%，代表這個策略，在空頭市場其實並不管用，這也可以說明，為何坊間有些號稱很厲害的籌碼方面的工具，在空頭市場使用者必須很小心使用的原因。不過如果單單看勝率，這個很簡單的策略，卻有著很不錯的勝率。

另外再次說明一下，我一直相信，特定的選股策略，搭配特定的進場策略，比較容易組合出可以實戰的交易策略，我是比較難找到放諸1700檔股票，在波段上皆適用的策略，所以我介紹的這些以日線為基礎的交易策略，通常都會搭配一個選股策略跟一個警示策略，在設定策略雷達時，必須如下圖般，在執行商品時選擇“選股”，然後使用特定的選股策略。

這點是要跟大家特別說明的

如果股價淨值比接近十年低點，通常有兩種情況，一種是底部到了大股東的最後防線，另一種則是公司的基本面在惡化中，這時候如果三日均線能突破十日均線，那麼第一種的機率會高一些。於是，我找出PB接近十年低點的股票，然後在三日均線如果突破十日均線時進場，停損停利都設為7%，回測的結果發現，這樣的交易策略，有很不錯的勝率，而且風險也不高，今天就介紹給大家。

選股策略

input:r1(10); setinputname(1,"PB距離N個月來低點只剩N%");
input:r2(60); setinputname(2,"N個月以來");
//input:TXT("僅適用月資料"); setinputname(3,"使用限制");
setbarfreq("M");

if barfreq <> "M" then raiseruntimeerror("頻率錯誤");

value1=GetField("股價淨值比","M");
value2=lowest(GetField("股價淨值比","M"),r2);
value3=average(GetField("股價淨值比","M"),r2);

if value1 < value3 and value1 < value2*(1+r1/100)
and close cross over average(close,10)
then ret=1;

setoutputname1("股價淨值比");
outputfield1(value1);

以昨天為例，這個腳本選出來的股票如下

至於警示腳本，則是使用3日均線突破10日均線。

警示腳本

input: Shortlength(3); setinputname(1,"短期均線期數");
input: Longlength(10); setinputname(2,"長期均線期數");

settotalbar(8);
setbarback(maxlist(Shortlength,Longlength,6));

If Average(Close,Shortlength) crosses over Average(Close,Longlength) then Ret=1;

回測報告

停損停利都設為7%，因為PB都接近十年低點了，想說再跌7%的機會不大，回測過去兩年及四年的回測報告如下

這也是一個勝率在七成左右，交易次數蠻多且MDD不高的交易策略

這幾天外資連續買超，大盤又回到外資法人主控的格局，趁這機會，來跟大家介紹一個跟外資相關的交易策略，這個策略的作法是去尋找外資持股比例蠻高，過去一陣子沒有買，最近連續三天大買且股價開始暴量起漲的股票。

最近的盤外資作多很積極

這一波法人佔交易的比重動軋超過四成

所以今天來跟大家介紹一個跟外資相關的交易策略，接下來也來陸續介紹這一類的交易策略。

選股策略

value1=GetField("外資買賣超");
value2=GetField("外資持股比例");

if value2>10
and trueall(value1>500,3)
and barslast(trueall(value1>1000,3))[1]>20
then ret=1;

這個腳本是在尋找外資持股比例超過一成，最近三天外資買超都超過五百張，且上一次發生這樣的情況已經是20天前

警示策略

input: Length(20); setinputname(1,"計算期數");
input: VLength(10); setinputname(2,"均量期數");
input: volpercent(50); setinputname(3,"爆量增幅%");
input: Rate(5); setinputname(4,"離低點幅度%");

settotalbar(3);
setbarback(maxlist(Length,VLength));

if Close > Close[1] and
Volume >= average(volume,VLength) *(1+ volpercent/100) and
Close <= lowest(close,Length) * (1+Rate/100)
then ret=1;

這裡用的是系統內建的暴量剛起漲

回測報告

用這樣的選股策略結合警示腳本所組合而成的策略雷達，如果出場點停損停利俱為7%，2年及5年的回測報告如下

這策略的勝率很高，過去五年甚至達到四戰三勝，MDD也低，最高才一成左右，缺點是因為條件太嚴，所以交易次數不多，連帶的年平均報酬也不到10%，大家可以調整參數把條件放寬一些，應該會有更多的交易機會。

連續介紹了幾個從基本面出發的策略，今天跟大家分享一個也是從基本面出發，勝率接近七成的交易策略，這個策略是去尋找過去幾年，常常盈餘成長率高過營收成長率的公司，因為這樣的公司，有的是因為達到經濟規模，有的是產品的毛利率在增加，有的是開始進入收成期，我們挑到這些公司之後，當他們開始價量俱揚時，往往就是好的進場點。

下面就跟大家分享要完成這樣的策略雷達，所要使用的選股及警示策略

選股策略

condition1=false;
value1=GetField("營收成長率","Y");
value2=GetField("稅後淨利成長率","y");
value3=GetField("本期稅後淨利","Y");//單位:百萬

if value1>0//年營收是成長的
and value2>0//年盈餘也是成長的
and value2>value1
//盈餘成長率大於營收成長率
then condition1=true;

if countif(condition1,5)>=3
//過去五年至少3年符合上述情形
and value3>200
//年稅後淨利超過2億元
then ret=1;

警示策略

Input: day(60,"日期區間");
Input: ratioLimit(14, "區間最大漲幅%");

Condition1 = H=highest(H,day);
//今日最高創區間最高價

Condition2 = V=highest(v,day);
//今日成交量創區間最大量

Condition3 = highest(H,day) < lowest(L,day)*(1 + ratioLimit*0.01);
//今日最高價距離區間最低價漲幅尚不大

if Condition1 And Condition2 And Condition3
then ret=1;

回測報告

一樣是停損停利都設為7%，過去兩年及五年的回測報告分別如下

這是一個勝率接近七成，年平均報酬率約10%的交易策略

這一系列介紹了不少從籌碼，基本面，估值等不同方面作出發的交易策略，有XS權限的朋友可以在盤中開啟這些策略雷達，我的經驗是每天多少會有值得留意的標的。

昨天介紹了毛利及毛利率好轉的基面面交易策略，今天再來介紹一個好公司營運好轉且暴量起漲的交易策略，營運有沒有好轉，從季報上來看，如果資產報酬率在成長，長期負債在減少，流動比率在好轉，毛利率變更好，那麼應該代表公司創造現金的能力在好轉，特別是如果營運現金流大於稅後盈餘，更是具有這樣的意義。 所以我根據這樣的想法來擬定選股策略

選股策略

其中最後一項是用選股腳本寫的，腳本如下

settotalbar(3);

value1=GetField("來自營運之現金流量","Q");
value2=GetField("本期稅後淨利","Q");
if value1 > value2
then ret=1;

警示腳本

 Input: day(60,"日期區間");
Input: ratioLimit(14, "區間最大漲幅%");

Condition1 = H=highest(H,day);
//今日最高創區間最高價

Condition2 = V=highest(v,day);
//今日成交量創區間最大量

Condition3 = highest(H,day) < lowest(L,day)*(1 + ratioLimit*0.01);
//今日最高價距離區間最低價漲幅尚不大

if Condition1 And Condition2 And Condition3
then ret=1;

回測報告

這裡一樣是回測過去兩年及五年，停損停利一樣都設7%，回測報告如下

這是一個有非常高週轉率且MDD可接受而且勝率蠻高的一個交易策略

尋找高勝率的交易策略，可以從不同的面向來著手，先前跟大家分享了幾個價值型的交易策略，今天換個口味，從基本面出發，要來跟大家分享毛利創新高的交易策略。

這個策略的概念是，營業毛利創五季新高，而且連兩季毛利率成長，代表公司體質有變好，加上毛利率要大於8%，代表這個行業有一定的利潤，如果這樣的公司每天成交值不到五億，代表還沒有成為熱門股，這時候如果開始暴量起漲，就可能是一個進場的訊號。

接下來跟大家介紹這個策略的選股條件及訊號觸發腳本

選股策略

我使用的選股條件如下

警示腳本

 Input: day(60,"日期區間");
Input: ratioLimit(14, "區間最大漲幅%");

Condition1 = H=highest(H,day);
//今日最高創區間最高價

Condition2 = V=highest(v,day);
//今日成交量創區間最大量

Condition3 = highest(H,day) < lowest(L,day)*(1 + ratioLimit*0.01);
//今日最高價距離區間最低價漲幅尚不大

if Condition1 And Condition2 And Condition3
then ret=1;

回測報告

這樣組合而成的策略雷達，回測過去兩年及五年，停損停利設為7%，回測報告分別如下

勝率，平均報酬率及MDD都非常不錯。