Author Archives: 發財橘子

江湖有種傳說：好公司如果週RSI跌到20以下，再次突破20時，就是一個好買點，以前我在老東家工作時，的確是有個營運員靠這一招在天母買房（當年的天母可比今天的信義區啊），今天的實驗室，來跟大家討論這個江湖傳說，能否形成一個可以實戰的交易策略。

先前有個網紅教大家用八週的RSI來決定0050的進場及出場點：

這個作法勝率頗高，但交易次數不多。

我把這樣的想法寫成以下的腳本：

if barfreq<>"W" then raiseRunTimeError("請改用週頻率");
input:period(8,"期間");
value1=rsi(close,period);
if value1 cross over 20
then ret=1;

然後用週K線去跑電子股前100檔，停損停利都設為20%，回測過去五年的報告如下：

這個作法用在電子股前100檔時，勝率是真的蠻高的，但在空頭市場其實還是會輸，而且MDD也是會超過20%。

所以這還是一個多頭市場限定版的市場傳說，在空頭市場時，還是要謹慎。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

下面這個腳本是地緣券商連續五天買超大於200張：

input:period(5,"最近n日");
value1=GetField("地緣券商買賣超張數","D");
if trueall(value1>200,period)
then ret=1;

如果這個腳本去回測過去五年所有普通股，停損停利都設為1%，回測報告如下：

這樣的績效及勝率其實算是不錯，MDD-20%也在可忍受範圍，但就是有個缺點，一是五年交易次數591次，一年平均超過100次，有點過度交易的情況，其次是五年總報酬70%，平均一年下來也沒有特別突出的好表現。

我試著加上一些量價的濾網，組成以下的選股策略：

結果勝率有高一點，交易次數也有少一點，但總報酬還是不算突出。

所以我回頭檢視回測報告裡的交易分析，按報酬率排序，發現輸錢的案例很多都是公司在台北市區或是市值頗大的權值股。所以在實戰上，當符合地緣券商連續買超的條件後，不妨再檢視看看這些股票是不是權值股？是不是位於台北市內？

整個實驗下來，地緣券商的確是一個很值得應用的選股因子，至於要連續幾天買超多少張最有效，進場後要多少%停損停利，就讓大家自己去做實驗了。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

昨天討論PB河流圖應用面的市場傳說，今天接著討論PE河流圖的應用方式，跟PB河流圖一樣，市場傳說如果股價跌到本益比接近五年的低位區，而且法人開始大買超，那就是一個值得留意的買點。下圖就是最近符合這個條件的一個例子：

根據這樣的說法，我寫了一個腳本如下，用來找出目前股價對應的本益比位低於五年低位區。

value1=lowest(getField("本益比", "D"),200);
value2=lowest(getField("本益比", "D"),400);
value3=lowest(getField("本益比", "D"),600);
value4=lowest(getField("本益比", "D"),800);
value5=lowest(getField("本益比", "D"),1000);
value6=(value1+value2+value3+value4+value5)/5;
if getField("本益比", "D")<value6*1.1
then ret=1;

用這個腳本再搭配近3日三大法人合計買超佔成交量1成以上的選股條件，合組成一個選股策略。

我把這個選股策略拿去回測過去五年的非金融股，停損停利都設為7%。

回測報告如下：

如果把停損停利改成20%，回測報告如下：

從這樣的回測結果來看，PE在歷史低點法人進場的勝率不如PB，符合條件的個股檔數則多非常的多，跟 PB歷史低點法人進場的情況一樣，都需要再去設其他的過濾條件才行，例如把法人買超改成關鍵券商買超之類的，都可以減少交易次數，提高勝率。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

這篇要跟大家討論的市場傳說屬於價值型投資，最近很流行河流圖，有一種說法是，如果股價淨值比接近這幾年的低點區，而且法人有明顯抄底的動作，那麼這就是一個很值得注意的作多機會。今天我們就來作實驗看看這樣的說法有沒有道理。

首先一樣是先寫個腳本來找那些股價淨值比在五年低點附近的股票：

input:r1(5,"PB距離N個月來低點只剩N%");
input:r2(60,"N個月以來");
setbarfreq("M");
if barfreq <> "M" then raiseruntimeerror("頻率錯誤");
value1=GetField("股價淨值比","M");
value2=lowest(GetField("股價淨值比","M"),r2);
value3=average(GetField("股價淨值比","M"),r2);
if value1 < value3 and value1 < value2*(1+r1/100)
then ret=1;

在這個腳本之外，再另外加上近三日三大法人買超合計佔成交量10%以上的條件，結合這兩個條件，組合成上述市場傳說的選股策略

接著拿這個選股策略去回測過去五年，因為是價值型投資，停損停利都設為20%。

回測的結果如下圖：

勝率是68.75%，這表示PB跌到近幾年的低點，而且法人開始用力抄底，的確是一個值得注意的訊號，不過在操作上，應該加入更多的過濾條件，不然這麼高的勝率，總報酬只有50%，代表獲利時有大量的個股都符合條件，分散了每筆的報酬，如果加上合適的過濾條件，應該可以提高這個選股策略的報酬率。

另外這個策略在崩盤時表現會很不好，特別是像上次疫情這種時候，這種停損設20%還因為意外利空而被停損，對報酬率是蠻傷的

整體來說，這個市場傳說的勝率是蠻高的，難怪有那麼多人喜歡用河流圖表那些股價非常接近PB低點，且法人大買的股票，不過就像回測所呈現的，符合這種情況的股票在大盤殺到低點時有一大串，還是得有其他的過濾條件來優化這個交易策略。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

這一期的股市傳說，我們來討論大股東連續買超，到底是不是一個很值得參考的買進訊號。

以下圖為例：

彩晶在連續四天代表大股東進出的關鍵券商都買超>500張之後，開啟了一波反彈行情。

所以我們今天就來聚焦這個議題： 大股東連續買進是不是一個買進訊號？

首先還是先解釋一下XQ關鍵券商的定義：

所謂的關鍵券商，其實就是公司派，要被列入為一檔個股的關鍵券商，一定是近三年內，這檔個股有真的實施庫藏股，然後系統根據庫藏股的公告，回頭去找那段時間大買超的券商分公司，把這些券商分公司就列為該個股的關鍵券商，也因此，如果近三年沒有實施庫藏股，那麼那檔個股就不會有關鍵券商。

為什麼這麼做呢？因為我們想要從籌碼中找出公司派進出的號子，一個常用的做法是透過地緣關係，但這個方法不適用雙北的公司，所以我們就想說實施庫藏股時，公司要買的金額通常會比較大，而且一定會下在跟公司常往來的券商分點，所以就決定用這個方法來定義關鍵券商。

接下來對照這個概念的腳本如下：

value1=GetField("關鍵券商買賣超張數","D");
if trueall(value1>500,4) 
then ret=1;
outputfield(1,value1,0,"關鍵券商買超張數");

這個腳本是找出連續四天大股東買超都超過500張的股票。

把這個腳本拿去回測過去五年，停損停利都設為7%，回測的報告如下：

勝率達到64% ，MDD只有12.6%。

這算是一個還蠻值得更深入研究的市場傳說，大股東進場果然是股價止跌回升的重要參考因素。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

今天我們來討論的江湖傳說是：如果目前的總市值遠低於「過去十年來自營運的現金流量的總和」，那麼就值得長期投資。

這個江湖傳說好像起源於美國那些價值型投資者，他們的意思是，如果有家公司目前的總市值，遠低於過去十年本業可以賺進來的現金流量，那麼應該是一個長線的買點。

美國有很多獲利穩定的公司，但台灣這種公司比較少，這樣的規則是否依然適用？

我寫了以下的腳本，想要來回測看看：

value1=getField("來自營運之現金流量", "Y")+getField("來自營運之現金流量", "Y")[1] 
+getField("來自營運之現金流量", "Y")[2]+getField("來自營運之現金流量", "Y")[3]
+getField("來自營運之現金流量", "Y")[4]+getField("來自營運之現金流量", "Y")[5]
+getField("來自營運之現金流量", "Y")[6]+getField("來自營運之現金流量", "Y")[7]
+getField("來自營運之現金流量", "Y")[8]+getField("來自營運之現金流量", "Y")[9];
//過去十年來自營運之現金流量總和,單位百萬
value2=getField("總市值(億)", "D");
input:ratio(80,"折價比例");
if (value1/100)/value2>=(1+ratio/100)
then ret=1;
outputfield(1,value1/100,0,"十年營運現金流總和(億)");
outputfield(2,value2,0,"總市值(億)");
outputfield(3,(value1/100)/value2,2,"佔比");

這個腳本設的折價幅度是打八折，回測過去五年，持有60天，報告如下：

勝率是56.5%。

如果折價幅度變成六成的話，回測七年的報告如下：

勝率接近60%，且績效遠優於大盤。

顯然這個江湖傳說在台灣也有一部份是可以適用的。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

這一期來談增資股出籠是不是重大利空？

先說結論：現增股快上市前兩天再去放空輸多贏少，反而是一個作多時機。

但如果是上市前15天去空，則輸少贏多。

市場上的傳說是，如果現增張數佔股本的比例夠高，且無法放空鎖單，或放空的張數不多，在增資股出籠前，會有一波賣壓，可以做個短空。

為了驗證這個江湖傳說，我寫了以下的腳本：

value1=GetField("現增新股上市日");
value2=GetField("現增比率");//每千股可認股數
value3=GetField("現增價格");
value4=GetField("融券餘額張數","D");
value5=GetField("普通股股本","Q");//單位:億

if value1>date and datediff(value1,date)<2//增資股快上市了
and 
value5*10000*value2/1000>10000//增資張數大於10000張
and 
value4[30]>value4-1000//近一個月融券增加沒有超過1000張
and
value3*1.1<close//股價仍比現增價格高超過一成
then ret=1;
outputfield(1,value1,0,"新股上市日");
outputfield(2,value2,0,"現增比率");
outputfield(3,close-value3,0,"現增價差");

一樣回測過去五年，停損停利都設7%，回測報告如下：

如果是等到增資股快出籠前兩天才去空，勝率很低，反而是作多，勝率竟然高達67%。

顯示大部份的公司，都不願意馬上就讓現金增資的參加者虧到錢。

如果把腳本改成以下的腳本：

value1=GetField("現增新股上市日");
value2=GetField("現增比率");//每千股可認股數
value3=GetField("現增價格");
value4=GetField("融券餘額張數","D");
value5=GetField("普通股股本","Q");//單位:億

if value1>date and datediff(value1,date)<15//增資股快上市了
and 
value5*10000*value2/1000>10000//增資張數大於10000張
and 
value4[30]>value4-2000//近一個月融券增加沒有超過2000張
and
value3*1.1<close//股價仍比現增價格高超過一成
then ret=1;
outputfield(1,value1,0,"新股上市日");
outputfield(2,value2,0,"現增比率");
outputfield(3,close-value3,0,"現增價差");



作空的回測報告如下

這顯示如果在離增資股出籠較早之前，像是前15日，然後放寬融券餘額上限到2000張，這時放空反而比較有勝算。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

這一期我們來談的是，股價站上布林值上軌且主力買超達到一定水準，是不是一個好的交易策略？

我寫的腳本如下：

value1=GetField("籌碼鎖定率","D");
Input: Length(20, "期數"), UpperBand(2, "通道上緣");
settotalbar(3);
if value1 >= 7
and close >= bollingerband(Close, Length, UpperBand)
then ret=1;

這裡的籌碼鎖定率，是股本減去董監持股作分母，主力買超作分子。

回測過去七年，停損停利都設為7%，回測報告如下：

雖然勝率也是接近50%，但績效不好。

如果是單純的K棒突破布林值上緣：

close cross Above bollingerband(Close, Length, UpperBand)

回測報告如下：

也就是說，股價突破布林值上限，本身是一個不錯的概念，可以搭配再去找其他的獲利因子，但主力大買超顯然未必是靠譜的因子。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

這一期我們來做實驗的市場傳說是：法人持續一直買的低價股是不是好的買進標的？

下面這張圖是這一概念下的成功例子：

這個選股方法要符合以下幾個條件：

一、股價目前不在近期最高點

二、前一日法人買超>800張

三、最近一日法人買超>1000張

四、過去一陣子大部份的日子法人都買超

五、目前股價<40元

我寫的腳本如下：

value1=getField("法人買賣超張數", "D");
input:period(12);
if close<highest(close,period)
//股價低於計算區間的最高點
and countif(value1>0,period)>period*0.75
//3/4的日子裡法人買超
and value1>1000
//近一個交易日法人買超達1000張以上
and value1[1]>800
//前一個交易日法人買超達800張以上
and close<40
then ret=1;

回測過去兩年，停損停利都設7%，報告如下：

勝率有6成，MDD是-17%，交易次數有226次。

這是一個聽起來很有道理，在多頭市場末升段漲到低價股時表現會特別好的選股策略。

我們面對這種勝率高，交易次數不多，在特定時段特別有用的選股策略，有兩個做法，一個是作為可以運用的選股策略之一，但不能單單使用這一交易策略；另一個做法則是研究其勝率高的原因，重新調整參數或加入其他條件。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

這一期我們來討論一個常見的江湖傳說：當KD與MACD同時出現買進訊號時，是不是一個多頭訊號？

我在好多個地方都有看到KOL在教大家，同時用多個技術指標來綜合研判進場點，類似像下面這張圖：

這個選股策略要符合幾個條件：

一、MACD的OSC翻紅

二、KD低當黃金交叉

三、RSI在50以上

要符合上述三個條件，我寫了以下的腳本：

input: Length_D(9,"日KD期間");
variable:rsv_d(0),kk_d(0),dd_d(0),c5(0);
stochastic(Length_D, 3, 3, rsv_d, kk_d, dd_d);

input:FastLength(12, "DIF短期期數");
input:SlowLength(26, "DIF長期期數");
input:MACDLength(9, "MACD期數");
variable: difValue(0), macdValue(0), oscValue(0);

MACD(weightedclose(), FastLength, SlowLength, MACDLength, difValue, macdValue, oscValue);

if kk_d crosses over dd_d
and kk_d<30
and oscValue Crosses Above 0
and rsi(close,10)>=50
then ret=1;


這個腳本回測過去七年，停損停利都設為7%，回測報告如下：

雖然勝率有55%，但其實績效算蠻差的，根本不是一個真的可能拿來實戰的交易策略。

要從裡頭挑像上圖這種看起來很威的標的是不難，但要真的這樣下去操作，恐怕會白忙一場。

我有試著把RSI這條件拿掉，改成近5日RSI趨勢是往上。

and linearRegSlope(rsi(close,10),5)>0

回測的結果如下：

雖然回測的數據好一點，但仍然輸給大盤不少，這樣無法實戰，我的建議是，在技術指標出現買進訊號時，不要再去搭配其他技術指標，試著加一些籌碼面的過濾條件，效果可能會好一些，如果一定要加其他技術指標，最好加一些比較具互補性的指標。

舉個例子，我寫過一篇DMI搭配VHF的文章

這裡面我提到了如何用VHF指標來過濾掉DMI指標跑出來的假買進訊號。

我們使用這樣的概念，再配合主力買超佔成交量兩成這個條件，可以寫出以下的腳本：

input: Length(24, "天數");
Variable: hp(0), lp(0), numerator(0), denominator(0), _vhf(0);
hp = highest(Close, Length);
lp = lowest(Close, Length);
numerator = hp - lp;
denominator = Summation(absvalue((Close - Close[1])), Length);
if denominator <> 0 then
_vhf = numerator / denominator
else
_vhf = 0;
input:period(14); setinputname(1,"計算期數");
variable: pdi(0), ndi(0), adx_value(0);
DirectionMovement(period, pdi, ndi, adx_value);
value1=getField("主力買賣超張數", "D");
if volume<>0 then 
value2=value1/volume*100;
if pdi>pdi[1] and ndi<ndi[1] and pdi crosses over ndi
and rsi(_vhf,5)>70
and value2>=20
then ret=1;

用這個腳本去回測過去七年，停損停利都設為7%，回測的結果如下圖：

雖然勝率只有58%，但收益曲線算是蠻平滑，MDD接近16%，在可接受範圍，在空頭市場也有一定的抵抗力，大家根據這樣的思維，可以試著打造自己的多指標交易策略。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！