綜合抄底策略

近期的股價修正，讓抄底策略開始有了用武之地，之前跟大家提過，在股價修正四成之後，有不少抄底型的交易策略勝率會大幅攀昇，今天跟大家介紹的方法是，把不同的抄底策略全部綜合在一個腳本中，只要股價修正超過四成之後，符合其中任何一種現象，都會觸發訊號。

自從有了XS之後，我應該寫超過500個腳本，回測下來，跌幅超過四成後的各種訊號，勝率真的比較高。

例如到昨天收盤價為止，近百日跌幅超過四成，成交量超過五百張且股價高於十元的股票如下圖

這些股票反彈起來，有不少還真的是又兇又猛。

並不是所有跌四成的股票都能買，之前跟大家分享過幾個抄底策略，如果下跌四成後又出現這些現象，進場作多的勝率往往超過六成。我把這些策略綜合在一個腳本中，希望可以節省各位的時間，

我寫的腳本如下

複製
1if close*1.4<highest(close,60)then begin
2variable:count(0);
3count=0;
4//之前無長紅，最近兩根長紅
5input:ratio(5,"長紅的漲幅下限");
6if countif(close[5]>=close[6]*(1+ratio/100),60)=0
7and countif(close>=close[1]*(1+ratio/100),5)>=2
8then count=count+1;
9
10//均線糾結後上漲
11input: s1(5,"短期均線期數");
12input: s2(10,"中期均線期數");
13input: s3(20,"長期均線期數");
14input: Percent(2,"均線糾結區間%");
15input: Volpercent(25,"放量幅度%");
16//帶量突破的量是超過最長期的均量多少%
17variable: shortaverage(0);
18variable: midaverage(0);
19variable: Longaverage(0);
20
21if volume > average(volume,s3) * (1 + volpercent * 0.01)
22//放量25%
23and lowest(volume,s3)<1000
24//區間最低量小於一千張
25and volume>2000
26//今日成交量突破2000張
27then begin
28shortaverage = average(close,s1);
29midaverage = average(close,s2);
30Longaverage = average(close,s3);
31value1= absvalue(shortaverage -midaverage);
32value2= absvalue(midaverage -Longaverage);
33value3= absvalue(Longaverage -shortaverage);
34value4= maxlist(value1,value2,value3);
35if value4*100 < Percent*Close
36and linearregangle(value4,5)<10
37then count=count+1;
38end;
39//低檔五連陽
40if trueall(close>open,5) 
41then count=count+1;
42//急拉
43value11=barslast(close>=close[1]*1.07);
44if value11[1]>50
45//超過50天沒有單日上漲超過7%
46and value11=0
47//今天上漲超過7%
48and average(volume,100)>500
49and volume>1000
50then count=count+1;
51//連續跳空上漲
52
53if countif(open > close[1],5)>=3
54//過去五天有三天以上開盤比前一天收盤高
55and average(volume,5)>2000
56//五日均量大於2000張
57then count=count+1;
58
59//連續多日價量回溫
60input:period(5,"回溫期數");
61value21=GetField("資金流向");
62value22=GetField("強弱指標","D");
63if countif(value21>value21[1]and value22>0,period)>= 4
64and volume>average(volume,20)*1.3
65then count=count+1;
66
67//主力回頭收集
68input:period1(20);
69value31=GetField("分公司賣出家數")[1];
70value32=GetField("分公司買進家數")[1]; 
71if linearregslope(value31,period1)>0
72//賣出的家數愈來愈多
73and linearregslope(value32,period1)<0
74//買進的家數愈來愈少
75and 
76close*1.03<close[1]
77//今天又跌超過3%
78 
79then count=count+1;
80
81
82if count>=1 then ret=1;
83end;
if close*1.4<highest(close,60)then begin
variable:count(0);
count=0;
//之前無長紅，最近兩根長紅
input:ratio(5,"長紅的漲幅下限");
if countif(close[5]>=close[6]*(1+ratio/100),60)=0
and countif(close>=close[1]*(1+ratio/100),5)>=2
then count=count+1;

//均線糾結後上漲
input: s1(5,"短期均線期數");
input: s2(10,"中期均線期數");
input: s3(20,"長期均線期數");
input: Percent(2,"均線糾結區間%");
input: Volpercent(25,"放量幅度%");
//帶量突破的量是超過最長期的均量多少%
variable: shortaverage(0);
variable: midaverage(0);
variable: Longaverage(0);

if volume > average(volume,s3) * (1 + volpercent * 0.01)
//放量25%
and lowest(volume,s3)<1000
//區間最低量小於一千張
and volume>2000
//今日成交量突破2000張
then begin
shortaverage = average(close,s1);
midaverage = average(close,s2);
Longaverage = average(close,s3);
value1= absvalue(shortaverage -midaverage);
value2= absvalue(midaverage -Longaverage);
value3= absvalue(Longaverage -shortaverage);
value4= maxlist(value1,value2,value3);
if value4*100 < Percent*Close
and linearregangle(value4,5)<10
then count=count+1;
end;
//低檔五連陽
if trueall(close>open,5) 
then count=count+1;
//急拉
value11=barslast(close>=close[1]*1.07);
if value11[1]>50
//超過50天沒有單日上漲超過7%
and value11=0
//今天上漲超過7%
and average(volume,100)>500
and volume>1000
then count=count+1;
//連續跳空上漲

if countif(open > close[1],5)>=3
//過去五天有三天以上開盤比前一天收盤高
and average(volume,5)>2000
//五日均量大於2000張
then count=count+1;

//連續多日價量回溫
input:period(5,"回溫期數");
value21=GetField("資金流向");
value22=GetField("強弱指標","D");
if countif(value21>value21[1]and value22>0,period)>= 4
and volume>average(volume,20)*1.3
then count=count+1;

//主力回頭收集
input:period1(20);
value31=GetField("分公司賣出家數")[1];
value32=GetField("分公司買進家數")[1]; 
if linearregslope(value31,period1)>0
//賣出的家數愈來愈多
and linearregslope(value32,period1)<0
//買進的家數愈來愈少
and 
close*1.03<close[1]
//今天又跌超過3%
 
then count=count+1;


if count>=1 then ret=1;
end;

我拿這個腳本去回測，並且對照單一腳本在沒有選股，沒有大盤濾網下的回測數據，作成以下的這張表

以上是跑所有股票，回測過去兩年，二十天後出場的回測數據比較。

這個綜合的策略，交易次數夠多，勝率也夠高，除了在大空頭市場之外，表現非常的平穩。

抄底策略不只這幾個，例如我先前介紹過的大跌後的吊人線等，各位可以把收集得到，勝率夠高的策略都用同樣的寫法放在一起，這是小弟我認為最靠譜的交易策略了。

這種抄底策略的另一個好處是，停損點很好設，破底就停損。